" Vim syntax file
" Language:	BIND configuration file
" Maintainer:	Robin H. Johnson <robbat2@gentoo.org>
" Author:	Nick Hibma <nick@van-laarhoven.org>
" Changed:	2010-12-23
" Filenames:	named.conf, rndc.conf
" Location:	http://www.van-laarhoven.org/vim/syntax/named.vim
"
" Previously maintained by glory hump <rnd@web-drive.ru> and updated by Marcin
" Dalecki.
"
" Partially updated for BIND 9.7 (per BIND ARM) by Robin H. Johnson
" <robbat2@gentoo.org>, after nearly 4 years of no updates from Nick Hibma.
"
" This file could do with a lot of improvements, so comments are welcome.
" Please submit the named.conf (segment) with any comments.
"
" For version 5.x: Clear all syntax items
" For version 6.x: Quit when a syntax file was already loaded
if version < 600
  syntax clear
elseif exists("b:current_syntax")
  finish
endif

syn case match

if version >= 600
  setlocal iskeyword=.,-,48-58,A-Z,a-z,_
else
  set iskeyword=.,-,48-58,A-Z,a-z,_
endif

if version >= 600
  syn sync match namedSync grouphere NONE "^(zone|controls|acl|key|masters|view|server|logging|options|trusted-keys|managed-keys|statistics-channels)\>"
endif

let s:save_cpo = &cpo
set cpo-=C

" BIND configuration file

syn match	namedComment	"//.*$"
syn match	namedComment	"#.*$"
syn region	namedComment	start="/\*" end="\*/"
syn region	namedString	start=/"/ end=/"/ contained
" --- omitted trailing semicolon
syn match	namedError	/[^;{#]$/

" --- top-level keywords

syn keyword	namedInclude	include nextgroup=namedString skipwhite
syn keyword	namedKeyword	acl key masters nextgroup=namedIntIdent skipwhite
syn keyword	namedKeyword	server nextgroup=namedIdentifier skipwhite
syn keyword	namedKeyword	controls nextgroup=namedSection skipwhite
syn keyword	namedKeyword	logging nextgroup=namedLogSection skipwhite
syn keyword	namedKeyword	options nextgroup=namedOptSection skipwhite
syn keyword	namedKeyword	zone nextgroup=namedZoneString skipwhite
" TODO: these need better validation
syn keyword	namedKeyword	trusted-keys managed-keys nextgroup=namedIntSection skipwhite
" TODO: missing sections: statistics-channels view

" --- Identifier: name of following { ... } Section
syn match	namedIdentifier	contained /\k\+/ nextgroup=namedSection skipwhite
" --- IntIdent: name of following IntSection
syn match	namedIntIdent	contained /"\=\k\+"\=/ nextgroup=namedIntSection skipwhite

" --- Section: { ... } clause
syn region	namedSection	contained start=+{+ end=+};+ contains=namedSection,namedIntKeyword

" --- IntSection: section that does not contain other sections
syn region	namedIntSection	contained start=+{+ end=+}+ contains=namedIntKeyword,namedError,namedComment

" --- IntKeyword: keywords contained within `{ ... }' sections only
" + these keywords are contained within `key' and `acl' sections
syn keyword	namedIntKeyword	contained key algorithm
syn keyword	namedIntKeyword	contained secret nextgroup=namedString skipwhite

" + these keywords are contained within `server' section only
syn keyword	namedIntKeyword	contained bogus support-ixfr provide-ixfr request-ixfr edns nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedIntKeyword	contained transfers edns-udp-size max-udp-size nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedIntKeyword	contained transfer-format
syn keyword	namedIntKeyword	contained keys nextgroup=namedIntSection skipwhite
syn match	namedIntKeyword	contained /\<notify-source\s\+.*;/he=s+12 contains=namedQSKeywords
syn match	namedIntKeyword	contained /\<notify-source-v6\s\+.*;/he=s+15 contains=namedQSKeywords
syn match	namedIntKeyword	contained /\<transfer-source\s\+.*;/he=s+12 contains=namedQSKeywords
syn match	namedIntKeyword	contained /\<transfer-source-v6\s\+.*;/he=s+15 contains=namedQSKeywords
syn match	namedIntKeyword	contained /\<query-source\s\+.*;/he=s+12 contains=namedQSKeywords
syn match	namedIntKeyword	contained /\<query-source-v6\s\+.*;/he=s+15 contains=namedQSKeywords
syn keyword      namedIntKeyword  contained use-queryport-pool nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedIntKeyword	contained queryport-pool-ports queryport-pool-updateinterval nextgroup=namedNumber,namedNotNumber skipwhite

" + these keywords are contained within `controls' section only
syn keyword	namedIntKeyword	contained inet nextgroup=namedIPaddr,namedIPerror skipwhite
syn keyword	namedIntKeyword	contained unix nextgroup=namedString skipwhite
syn keyword	namedIntKeyword	contained port perm owner group nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedIntKeyword	contained allow nextgroup=namedIntSection skipwhite
" TODO: keys

" + these keywords are contained within `update-policy' section only
syn keyword	namedIntKeyword	contained grant nextgroup=namedString skipwhite
syn keyword	namedIntKeyword	contained name self subdomain wildcard nextgroup=namedString skipwhite
syn keyword	namedIntKeyword	TXT A PTR NS SOA A6 CNAME MX ANY skipwhite

" --- options
"  TODO: tkey-*
syn region	namedOptSection	contained start=+{+ end=+};+ contains=namedOption,namedCNOption,namedComment,namedParenError

syn keyword	namedOption	contained attach-cache version hostname server-id directory key-directory
\		nextgroup=namedString skipwhite
syn keyword	namedOption	contained managed-keys-directory named-xfer cache-file dump-file bindkeys-file pid-file
\		nextgroup=namedString skipwhite
syn keyword	namedOption	contained memstatistics zone-statistics
\		nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedOption	contained mem-statistics-file statistics-file bindkeys-file recursing-file
\		nextgroup=namedString skipwhite
syn keyword	namedOption	contained auth-nxdomain deallocate-on-exit
\		nextgroup=namedBool,namedNotBool skipwhite
" TODO: dialup takes other options
syn keyword	namedOption	contained dialup fake-iquery fetch-glue flush-zones-on-shutdown
\		nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedOption	contained host-statistics-max
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained has-old-clients host-statistics minimal-responses
\		nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedOption	contained maintain-ixfr-base multiple-cnames
\		nextgroup=namedBool,namedNotBool skipwhite
" TODO: ixfr-from-differences
syn keyword	namedOption	contained recursion rfc2308-type1
\		nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedOption	contained notify
\		nextgroup=namedBool,namedNotifyKeywords,namedNotBool skipwhite
syn keyword	namedOption	contained use-id-pool
\		nextgroup=namedBool,namedNotBool skipwhite
" TODO: dnssec-lookaside dnssec-must-be-secure
syn keyword	namedOption	contained dnssec-enable dnssec-validation dnssec-accept-expired
\		nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedOption	contained additional
\		nextgroup=namedBool,namedNotBool skipwhite
" TODO: allows 'IP port PORT'
syn keyword	namedOption	contained forwarders
\		nextgroup=namedIPlist skipwhite
" TODO; dual-stack-servers
syn keyword	namedOption	contained forward
syn keyword	namedOption	contained check-names
\	                 nextgroup=namedCheckKeywords,namedCNKeywords skipwhite
syn keyword	namedOption	contained check-dup-records check-mx check-mx-cname check-srv-cname
\	                 nextgroup=namedCheckKeywords skipwhite
syn keyword      namedOption      contained check-wildcard check-integrity check-sibling
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained allow-query allow-query-on allow-query-cache allow-query-cache-on
\		nextgroup=namedAML skipwhite
syn keyword	namedOption	contained allow-transfer allow-notify
\		nextgroup=namedAML skipwhite
syn keyword	namedOption	contained allow-recursion allow-recursion-on
\		nextgroup=namedAML skipwhite
syn keyword	namedOption	contained allow-update allow-update-forwarding
\		nextgroup=namedAML skipwhite
syn keyword      namedOption      contained update-check-ksk dnssec-dnskey-kskonly dnssec-secure-to-insecure
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword      namedOption      contained try-tcp-refresh
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained blackhole
\		nextgroup=namedIntSection skipwhite
" TODO: (use|avoid)-(v4|v6)-udp-ports
syn keyword      namedOption      contained use-queryport-pool
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained queryport-pool-ports queryport-pool-updateinterval
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained max-transfer-time-in max-transfer-time-out
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained max-transfer-idle-in max-transfer-idle-out
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained tcp-clients reserved-sockets recursive-clients
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained serial-query-rate serial-queries tcp-listen-queue
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained transfer-format
syn keyword	namedOption	contained transfers-in transfer-out transfers-per-ns
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained transfer-source transfer-source-v6
\		nextgroup=namedIPaddr,namedIPerror skipwhite
syn keyword      namedOption      contained use-alt-transfer-source
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained notify-delay
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained notify-source notify-source-v6
\		nextgroup=namedIPaddr,namedIPerror skipwhite
syn keyword      namedOption      contained notify-to-soa
\		nextgroup=namedBool,namedNotBool  skipwhite
" TODO: allows 'IP port PORT'
syn keyword	namedOption	contained also-notify
\		nextgroup=namedIPlist skipwhite
syn keyword	namedOption	contained max-ixfr-log-size
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained max-journal-size coresize datasize files stacksize
syn keyword	namedOption	contained cleaning-interval interface-interval statistics-interval heartbeat-interval
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained topology sortlist rrset-order
\		nextgroup=namedIntSection skipwhite
syn keyword	namedOption	contained lame-ttl max-ncache-ttl max-cache-ttl
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained sig-validity-interval sig-signing-nodes sig-signing-signatures sig-signing-type
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedOption	contained min-roots
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword      namedOption      contained use-ixfr provide-ixfr request-ixfr treat-cr-as-space
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained min-refresh-time max-refresh-time min-retry-time max-retry-time
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword      namedOption      contained port
syn keyword      namedOption      contained additional-from-auth additional-from-cache
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained random-device
\		nextgroup=namedString skipwhite
syn keyword      namedOption      contained max-cache-size
syn keyword      namedOption      contained match-mapped-addresses
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword      namedOption      contained filter-aaaa-on-v4 preferred-glue
syn keyword	namedOption	contained edns-udp-size max-udp-size
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword      namedOption      contained root-delegation-only
syn keyword      namedOption      contained querylog
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword      namedOption      contained disable-algorithms
syn keyword      namedOption      contained acache-enable
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword	namedOption	contained acache-cleaning-interval
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword      namedOption      contained max-acache-size
syn keyword	namedOption	contained clients-per-query max-clients-per-query
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword      namedOption      contained masterfile-format 
syn keyword      namedOption      contained empty-server empty-contact
\		nextgroup=namedString skipwhite
syn keyword      namedOption      contained empty-zones-enable
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword      namedOption      contained disable-empty-zone
\		nextgroup=namedString skipwhite
syn keyword      namedOption      contained zero-no-soa-ttl zero-no-soa-ttl-cache
\		nextgroup=namedBool,namedNotBool  skipwhite
syn keyword      namedOption      contained deny-answer-addresses deny-answer-aliases

syn keyword      namedNotifyKeywords    contained explicit master-only
syn keyword      namedCheckKeywords     contained warn fail ignore
syn match	namedCNOption	contained /\<check-names\s\+.*;/he=s+11 contains=namedCNKeywords,namedCheckKeywords
syn keyword	namedCNKeywords	contained master slave response

syn match	namedOption	contained /\<notify-source\s\+.*;/he=s+12 contains=namedQSKeywords
syn match	namedOption	contained /\<notify-source-v6\s\+.*;/he=s+15 contains=namedQSKeywords
syn match	namedOption	contained /\<transfer-source\s\+.*;/he=s+12 contains=namedQSKeywords
syn match	namedOption	contained /\<transfer-source-v6\s\+.*;/he=s+15 contains=namedQSKeywords
syn match	namedOption	contained /\<query-source\s\+.*;/he=s+12 contains=namedQSKeywords
syn match	namedOption	contained /\<query-source-v6\s\+.*;/he=s+15 contains=namedQSKeywords
syn keyword	namedQSKeywords	contained address port
syn match        namedOption      contained /\<listen-on\s\+.*;/he=s+9 contains=namedLOKeywords,namedIntSection
syn match        namedOption      contained /\<listen-on-v6\s\+.*;/he=s+12 contains=namedLOKeywords,namedIntSection
syn keyword      namedLOKeywords  contained port

" --- logging facilities
syn region	namedLogSection	contained start=+{+ end=+};+ contains=namedLogOption
syn keyword	namedLogOption	contained channel nextgroup=namedIntIdent skipwhite
syn keyword	namedLogOption	contained category nextgroup=namedIntIdent skipwhite
syn keyword	namedIntKeyword	contained syslog null versions size severity
syn keyword	namedIntKeyword	contained file nextgroup=namedString skipwhite
syn keyword	namedIntKeyword	contained print-category print-severity print-time nextgroup=namedBool,namedNotBool skipwhite

" --- zone section
syn region	namedZoneString	contained oneline start=+"+ end=+"+ skipwhite
\		contains=namedDomain,namedIllegalDom
\		nextgroup=namedZoneClass,namedZoneSection
syn keyword	namedZoneClass	contained in hs hesiod chaos
\		IN HS HESIOD CHAOS
\		nextgroup=namedZoneSection skipwhite

" TODO: verify all zone options
syn region	namedZoneSection	contained start=+{+ end=+};+ contains=namedZoneOpt,namedCNOption,namedComment,namedMasters,namedParenError
syn keyword	namedZoneOpt	contained file ixfr-base
\		nextgroup=namedString skipwhite
syn keyword	namedZoneOpt	contained notify dialup
\		nextgroup=namedBool,namedNotBool skipwhite
syn keyword	namedZoneOpt	contained pubkey forward
syn keyword	namedZoneOpt	contained max-transfer-time-in
\		nextgroup=namedNumber,namedNotNumber skipwhite
syn keyword	namedZoneOpt	contained type nextgroup=namedZoneType skipwhite
syn keyword	namedZoneType	contained master slave stub forward hint

syn keyword	namedZoneOpt	contained masters forwarders
\		nextgroup=namedIPlist skipwhite
syn region	namedIPlist	contained start=+{+ end=+};+ contains=namedIPaddr,namedIPerror,namedComment,namedParenError
syn keyword	namedZoneOpt	contained allow-update allow-query allow-transfer
\		nextgroup=namedAML skipwhite
syn keyword	namedZoneOpt	contained update-policy
\		nextgroup=namedIntSection skipwhite

" --- boolean parameter
syn match	namedNotBool	contained "[^ 	;]\+"
syn keyword	namedBool	contained yes no true false 1 0

" --- number parameter
syn match	namedNotNumber	contained "[^ 	0-9;]\+"
syn match	namedNumber	contained "\d\+"

" --- address match list
syn region	namedAML	contained start=+{+ end=+};+ contains=namedComment,namedParenError,namedString

" --- IPs & Domains
syn match	namedIPaddr      contained /\<[a-fA-F0-9:]*::[a-fA-F0-9:.]*/
syn match	namedIPaddr      contained /\<[a-fA-F0-9:]\+:[a-fA-F0-9:]\+:[a-fA-F0-9:.]\+/
syn match	namedIPaddr	contained /\<[0-9]\{1,3}\(\.[0-9]\{1,3}\)\{3}/
syn match	namedIPaddr      contained /\<[a-fA-F0-9:]*::[a-fA-F0-9:.]*;/he=e-1
syn match	namedIPaddr      contained /\<[a-fA-F0-9:]\+:[a-fA-F0-9:]\+:[a-fA-F0-9:.]\+;/he=e-1
syn match	namedIPaddr	contained /\<[0-9]\{1,3}\(\.[0-9]\{1,3}\)\{3};/he=e-1
syn match	namedDomain	contained /\<[0-9A-Za-z][-0-9A-Za-z.]\+\>/ nextgroup=namedSpareDot
syn match	namedDomain	contained /"\."/ms=s+1,me=e-1
syn match	namedSpareDot	contained /\./

" --- syntax errors
syn match	namedIllegalDom	contained /"\S*[^-A-Za-z0-9.[:space:]]\S*"/ms=s+1,me=e-1
syn match	namedIPerror	contained /\<\S*[^0-9.[:space:]a-fA-F:;]\S*/
syn match	namedEParenError	contained +{+
syn match	namedParenError	+}\([^;]\|$\)+

" Define the default highlighting.
" For version 5.7 and earlier: only when not done already
" For version 5.8 and later: only when an item doesn't have highlighting yet
if version >= 508 || !exists("did_named_syn_inits")
  if version < 508
    let did_named_syn_inits = 1
    command -nargs=+ HiLink hi link <args>
  else
    command -nargs=+ HiLink hi def link <args>
  endif

  HiLink namedComment	Comment
  HiLink namedInclude	Include
  HiLink namedKeyword	Keyword
  HiLink namedIntKeyword	Keyword
  HiLink namedIdentifier	Identifier
  HiLink namedIntIdent	Identifier

  HiLink namedString	String
  HiLink namedBool	Type
  HiLink namedNotBool	Error
  HiLink namedNumber	Number
  HiLink namedNotNumber	Error

  HiLink namedOption	namedKeyword
  HiLink namedLogOption	namedKeyword
  HiLink namedCNOption	namedKeyword
  HiLink namedQSKeywords	Type
  HiLink namedCNKeywords	Type
  HiLink namedCheckKeywords       Type
  HiLink namedLOKeywords          Type
  HiLink namedNotifyKeywords      Type
  HiLink namedLogCategory	Type
  HiLink namedIPaddr	Number
  HiLink namedDomain	Identifier
  HiLink namedZoneOpt	namedKeyword
  HiLink namedZoneType	Type
  HiLink namedParenError	Error
  HiLink namedEParenError	Error
  HiLink namedIllegalDom	Error
  HiLink namedIPerror	Error
  HiLink namedSpareDot	Error
  HiLink namedError	Error

  delcommand HiLink
endif

let &cpo = s:save_cpo
unlet s:save_cpo

let b:current_syntax = "named"

" vim: ts=17