set term svg enhanced
set output "gci_tasks.svg"

set title "GCI Tasks (as of 20101223)" \
	font "/usr/share/fonts/corefonts/arial.ttf,22"

set xlabel "# Tasks" \
	font "/usr/share/fonts/corefonts/arial.ttf,18" \
	offset 0,-1
set ylabel "Percentage" \
	font "/usr/share/fonts/corefonts/arial.ttf,18" \
	offset -3,0

set border 3 lw 1.0
set xtics nomirror font "/usr/share/fonts/corefonts/arial.ttf,18"
set ytics nomirror font "/usr/share/fonts/corefonts/arial.ttf,18"

set style fill solid border rgb "black"

#set key rmargin center Left reverse
#set key left Left reverse
set key center right
#set key box lw 1
#set size square

f(x) = 0

plot [0:32] \
'gci_tasks.csv' \
	u 3:(1./320.) \
	smooth cumulative \
	lc rgb "blue" \
	t '{//usr/share/fonts/corefonts/arial.ttf=14 Cumulative}', \
'gci_tasks.csv' \
	u 3:(1./320.) \
	smooth frequency \
	w boxes \
	lc rgb "red" \
	t '{//usr/share/fonts/corefonts/arial.ttf=14 Histogram}', \
'gci_tasks.csv' \
	u 3:(0.25*rand(0)-.35) \
	lc rgb "gray70" \
	pt 7 \
	ps 0.5 \
	t '', \
f(x) \
	lc rgb "gray70" \
	t ''